ZXNet эхоконференция «code.zx»
тема: #0A
от: Paul Falcon
кому: Sergey Romanov
дата: 17 May 1997
* Message from gate SpbZxNet<=>FidoNet.
>Hello All!
>Может кто подкинет программку убирания
>кодов 10 в тексте?
>Входные параметры:
>HL-адрес начала текста;
>BC-Длина текста в байтах;
>Выходные параметры:
>BC-новая длина текста.
>Hу кто возмется ? ;)
А что неужели так трудно ?
надо всего лишь , соорудить маленькую
процедурку.
ld ix,lenght; длинна кода
ld hl,start_adress;это начало
;всего текста программы
no_end ld a,(hl)
cp #0a
jr nz,no_0a
push hl
ld e,l
ld d,h
dec de
ld c,lx
ld b,hx
ldir; переброска оставшегося
;кода на 1 байт вниз
pop hl
dec hl
no_0a inc hl
dec lx
jr nz,no_end
dec hx
jr nz,no_end
ld de,start_adress
and a
sbc hl,de
ld c,l
ld b,h;новая длинна
ret
Короче я ее не проверял но смысл я
думаю понятен .
-+- зьасм (макроносый)
+ Origin: и тебе тоже .(812/03.00)
от: Michael Kondratyev
кому: Paul Falcon
дата: 19 May 1997
Hello Paul!
Sat May 17 1997, Paul Falcon (812/03.00) состряпал(а) письмо к Sergey Romanov:
PF> надо всего лишь , соорудить маленькую
PF> процедурку.
PF> ld ix,lenght; длинна кода
PF> ld hl,start_adress;это начало
PF> ld b,h;новая длинна
PF> ret
PF> Короче я ее не проверял но смысл я
PF> думаю понятен .
бpедъ. не пpоще ли такъ:
ld hl, start_address
ld bc, length
push bc
ld d, h
ld e, l
ld a, 0ah
@@loop:
cp (hl)
ldi
jr nz, @@next
dec de
@@next:
jp pe, @@loop
cp a
sbc hl, de
ex de, hl
pop hl
sbc hl, de ; new size
With best wishes, Michael.
|